mirror of
https://github.com/archlinux/aur.git
synced 2026-02-09 14:34:42 +01:00
48 lines
2 KiB
Bash
48 lines
2 KiB
Bash
# Maintainer: Christopher Cooper <christopher@cg505.com>
|
|
# Maintainer: Jérôme Poulin <jeromepoulin@gmail.com>
|
|
pkgname=claude-code
|
|
pkgver=2.1.37
|
|
pkgrel=1
|
|
pkgdesc="An agentic coding tool that lives in your terminal"
|
|
arch=('x86_64' 'aarch64')
|
|
url="https://github.com/anthropics/claude-code"
|
|
license=('LicenseRef-claude-code')
|
|
depends=('bash')
|
|
# Binary is a self-contained Bun executable with embedded JS/resources - stripping breaks it
|
|
options=('!strip')
|
|
optdepends=(
|
|
'git: allow Claude to use git'
|
|
'github-cli: interact with GitHub'
|
|
'glab: interact with GitLab'
|
|
'ripgrep: enhanced file search'
|
|
'tmux: agent team split panes'
|
|
)
|
|
|
|
# This bucket is used in the official install script at https://claude.ai/install.sh
|
|
# curl -fsSL https://claude.ai/install.sh | grep GCS_BUCKET
|
|
_gcs_bucket="https://storage.googleapis.com/claude-code-dist-86c565f3-f756-42ad-8dfa-d59b1c096819/claude-code-releases"
|
|
source=("LICENSE::https://raw.githubusercontent.com/anthropics/claude-code/refs/heads/main/LICENSE.md")
|
|
source_x86_64=("claude-${pkgver}-x86_64::${_gcs_bucket}/${pkgver}/linux-x64/claude")
|
|
source_aarch64=("claude-${pkgver}-aarch64::${_gcs_bucket}/${pkgver}/linux-arm64/claude")
|
|
|
|
sha256sums=('728158fd1037143fad6907e8fa34804177e598b7326519503fe83cafdef849e6')
|
|
sha256sums_x86_64=('f967a4d06e16a32436b6329e2dbed459a9fa4d34f07635a1fb271b74f706c91f')
|
|
sha256sums_aarch64=('d725cc73060f400a7ac03a769969397daec9d411dbd5b1c7bb1fa60427bf657e')
|
|
|
|
package() {
|
|
install -Dm755 "${srcdir}/claude-${pkgver}-${CARCH}" "${pkgdir}/opt/claude-code/bin/claude"
|
|
|
|
# Create wrapper script that sets NPM_CONFIG_PREFIX to avoid false npm detection
|
|
install -dm755 "${pkgdir}/usr/bin"
|
|
cat > "${pkgdir}/usr/bin/claude" << 'EOF'
|
|
#!/bin/sh
|
|
# Wrapper to prevent claude from detecting /usr/bin/claude as npm-global installation
|
|
export NPM_CONFIG_PREFIX="${NPM_CONFIG_PREFIX:-/nonexistent}"
|
|
# Disable autoupdater
|
|
export DISABLE_AUTOUPDATER=1
|
|
exec /opt/claude-code/bin/claude "$@"
|
|
EOF
|
|
chmod 755 "${pkgdir}/usr/bin/claude"
|
|
|
|
install -Dm644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
|
|
}
|