jq := require("jq")
vercmp := require("vercmp")
makepkg := require("makepkg")
nvchecker := require("nvchecker")

latest_version := `nvchecker -c .nvchecker.toml --logger json | jq -r '.version'`

print-latest:
  @echo "Latest version is {{latest_version}}"

bump:
  #!/bin/sh
  set -e

  current="$(grep 'pkgver=' PKGBUILD | grep -Eo '[0-9]+\.[0-9]+\.[0-9]+')"
  echo "Current version: $current"

  latest="{{latest_version}}"
  echo "Latest version: $latest"

  if [ "$(vercmp "$current" "$latest")" -ne "-1" ]; then
    echo "No version bump needed"
    exit
  fi

  echo "Bumping version to $latest"
  sed -i "s/pkgver=.*/pkgver=$latest/" PKGBUILD
  sed -i "s/pkgrel=.*/pkgrel=1/" PKGBUILD

  just update-checksums

  git commit -am "chore: bump to v$latest"

update-checksums:
  #!/bin/sh
  set -e

  echo "Updating checksums"
  checksums="$(makepkg -g)"
  for arch in $(sed -nE 's/arch=\((.*)\)/\1/p' PKGBUILD); do
    arch="$(echo $arch | sed -E 's/"(.*)"/\1/g')"
    sed -i "s/sha256sums_$arch=.*/$(echo "$checksums" | grep "sha256sums_$arch")/" PKGBUILD
  done

  echo "Updating SRCINFO"
  makepkg --printsrcinfo > .SRCINFO

install:
  makepkg -f
  makepkg -si

clean:
  rm -rf *.tar.gz *.tar.xz *.zst ./src ./pkg