[add] smc-git

.SRCINFO

@@ -0,0 +1,24 @@
+pkgbase = smc-git
+	pkgdesc = Secret Maryo Chronicles
+	pkgver = 210.a0405c9
+	pkgrel = 1
+	url = http://www.secretmaryo.org
+	arch = i686
+	arch = x86_64
+	license = GPL3
+	makedepends = boost
+	makedepends = git
+	depends = sdl_image
+	depends = sdl_ttf
+	depends = sdl_mixer
+	depends = cegui-0.7
+	depends = boost-libs
+	depends = libgl
+	conflicts = smc
+	source = smc::git://github.com/FluXy/SMC.git
+	source = smc.desktop
+	md5sums = SKIP
+	md5sums = SKIP
+
+pkgname = smc-git
+

PKGBUILD

@@ -0,0 +1,40 @@
+# Maintainer: carstene1ns <arch carsten-teibes de>
+# Contributor: josephgbr <rafael.f.f1@gmail.com>
+
+pkgname=smc-git
+pkgver=210.a0405c9
+pkgrel=1
+pkgdesc="Secret Maryo Chronicles"
+arch=('i686' 'x86_64')
+url="http://www.secretmaryo.org"
+license=('GPL3')
+depends=('sdl_image' 'sdl_ttf' 'sdl_mixer' 'cegui-0.7' 'boost-libs' 'libgl')
+makedepends=('boost' 'git')
+conflicts=('smc')
+source=("smc"::"git://github.com/FluXy/SMC.git" "smc.desktop")
+md5sums=('SKIP' 'SKIP')
+
+pkgver() {
+  cd smc
+  echo $(git rev-list --count master).$(git rev-parse --short master)
+}
+
+build() {
+  cd smc/smc
+
+  ./autogen.sh
+  ./configure --prefix=/usr
+
+  make
+}
+
+package() {
+  cd smc/smc
+
+  make DESTDIR="$pkgdir/" install
+
+  # man and .desktop
+  install -Dm644 makefiles/unix/man/smc.6 "$pkgdir"/usr/share/man/man6/smc.6
+  install -Dm644 makefiles/unix/smc.xpm "$pkgdir"/usr/share/pixmaps/smc.xpm
+  install -Dm644 ../../smc.desktop "$pkgdir"/usr/share/applications/smc.desktop
+}

smc.desktop

@@ -0,0 +1,7 @@
+[Desktop Entry]
+Type=Application
+Name=Secret Maryo Chronicles
+Icon=smc
+TryExec=smc
+Exec=smc
+Categories=Game;ArcadeGame;