From ea87eff4dbca6e2fe357ce19ff64d2d642395151 Mon Sep 17 00:00:00 2001
From: Sven Schneider <postwar@web.de>
Date: Fri, 6 Apr 2012 17:09:12 +0200
Subject: [PATCH] added initial set of pkgbuilds

---
 .SRCINFO       | 18 +++++++++++++
 PKGBUILD       | 73 ++++++++++++++++++++++++++++++++++++++++++++++++++
 openni.install | 13 +++++++++
 3 files changed, 104 insertions(+)
 create mode 100644 .SRCINFO
 create mode 100644 PKGBUILD
 create mode 100644 openni.install

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..3e1a203248bc
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,18 @@
+pkgbase = openni-git
+	pkgdesc = The OpenNI Framework provides the interface for physical devices and for middleware components
+	pkgver = 20120319
+	pkgrel = 1
+	url = http://www.openni.org/
+	install = openni.install
+	arch = i686
+	arch = x86_64
+	license = GPL
+	makedepends = git
+	depends = freeglut
+	depends = libusb
+	depends = java-environment
+	provides = openni
+	conflicts = openni
+
+pkgname = openni-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..9423afa4ee69
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,73 @@
+# Maintainer: Sven Schneider <archlinux.sandmann@googlemail.com>
+# Contributor: bugix
+# Contributor: Lubosz Sarnecki <lubosz at gmail>
+
+pkgname=openni-git
+pkgver=20120319
+pkgrel=1
+pkgdesc="The OpenNI Framework provides the interface for physical devices and for middleware components"
+arch=('i686' 'x86_64')
+url="http://www.openni.org/"
+license=('GPL')
+depends=('freeglut' 'libusb' 'java-environment')
+makedepends=('git')
+provides=('openni')
+conflicts=('openni')
+install="openni.install"
+source=()
+md5sums=()
+
+_gitroot="git://github.com/OpenNI/OpenNI.git"
+_gitname="openni"
+_gitbranch="unstable"
+
+
+if [ "${CARCH}" = "x86_64" ]; then
+  _platform=x64
+else
+  _platform=x86
+fi
+
+
+build() {
+  cd "${srcdir}"
+  msg "Connecting to GIT server...."
+
+  if [ -d ${_gitname} ] ; then
+    cd ${_gitname} && git pull origin
+    msg "The local files are updated."
+  else
+    git clone -b ${_gitbranch} ${_gitroot} ${_gitname}
+  fi
+
+  msg "GIT checkout done or server timeout"
+  msg "Starting make..."
+
+  rm -rf "${srcdir}/${_gitname}-build"
+  git clone "${srcdir}/${_gitname}" "${srcdir}/${_gitname}-build"
+  
+  find "${srcdir}/${_gitname}-build/Samples" -type f -exec sed -i 's#../../../../Data/SamplesConfig.xml#/usr/share/openni/SamplesConfig.xml#g' {} \;
+  
+  cd "${srcdir}/${_gitname}-build/Platform/Linux/Build"
+
+  # BUILD
+  LDFLAGS+=' -lGL' make
+}
+
+package() {
+  install -d -m755 "${pkgdir}/usr/"{lib,bin,share/openni,include/ni/Linux-x86}
+  install -d -m755 "${pkgdir}/var/lib/ni"
+
+  cd "${srcdir}/${_gitname}-build/Include"
+  install *.h "${pkgdir}/usr/include/ni"
+  install Linux-x86/* "${pkgdir}/usr/include/ni/Linux-x86"
+  
+  cd "${srcdir}/${_gitname}-build/Data"
+  install SamplesConfig.xml "${pkgdir}/usr/share/openni"
+
+  cd "${srcdir}/${_gitname}-build/Platform/Linux/Bin/${_platform}-Release"
+  install niLicense niReg "${pkgdir}/usr/bin"
+  install Sample* "${pkgdir}/usr/bin"
+
+  install libnimCodecs.so libnimMockNodes.so libnimRecorder.so libOpenNI.so "${pkgdir}/usr/lib"
+}
diff --git a/openni.install b/openni.install
new file mode 100644
index 000000000000..94ec3d5a9264
--- /dev/null
+++ b/openni.install
@@ -0,0 +1,13 @@
+post_install() {
+	MODULES="libnimMockNodes.so libnimCodecs.so libnimRecorder.so"
+	for module in $MODULES
+	do 
+		/usr/bin/niReg /usr/lib/$module
+	done
+	
+	echo "Don't forget to install a hardware driver such as sensorkinect-git"
+}
+
+pre_remove() {
+	rm /var/lib/ni/modules.xml
+}