portty v0.1.0

.SRCINFO

@@ -0,0 +1,16 @@
+pkgbase = portty-git
+	pkgdesc = XDG Desktop Portal backend for TTY environments
+	pkgver = r4.2b533ff
+	pkgrel = 1
+	url = https://github.com/werdxz/portty
+	arch = x86_64
+	license = MIT
+	makedepends = cargo
+	makedepends = git
+	depends = xdg-desktop-portal
+	provides = portty
+	conflicts = portty
+	source = portty-git::git+https://github.com/werdxz/portty.git
+	sha256sums = SKIP
+
+pkgname = portty-git

PKGBUILD

@@ -0,0 +1,47 @@
+# Maintainer: werdxz
+
+pkgname=portty-git
+pkgver=r4.2b533ff
+pkgrel=1
+pkgdesc="XDG Desktop Portal backend for TTY environments"
+arch=('x86_64')
+url="https://github.com/werdxz/portty"
+license=('MIT')
+depends=('xdg-desktop-portal')
+makedepends=('cargo' 'git')
+provides=('portty')
+conflicts=('portty')
+source=("${pkgname}::git+https://github.com/werdxz/portty.git")
+sha256sums=('SKIP')
+
+pkgver() {
+    cd "$pkgname"
+    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+    cd "$pkgname"
+    cargo build --release --locked
+}
+
+package() {
+    cd "$pkgname"
+
+    # Install daemon
+    install -Dm755 "target/release/porttyd" "$pkgdir/usr/lib/portty/porttyd"
+
+    # Install builtin
+    install -Dm755 "target/release/portty-builtin" "$pkgdir/usr/lib/portty/portty-builtin"
+
+    # Install portal file
+    install -Dm644 "misc/tty.portal" "$pkgdir/usr/share/xdg-desktop-portal/portals/tty.portal"
+
+    # Install systemd service
+    install -Dm644 "misc/portty.service" "$pkgdir/usr/lib/systemd/user/portty.service"
+
+    # Install license
+    install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+
+    # Install example config
+    install -Dm644 "misc/config.toml.example" "$pkgdir/usr/share/doc/$pkgname/config.toml.example"
+}