Initial upload: hledger-lsp 0.2.4-1

.SRCINFO

@@ -0,0 +1,13 @@
+pkgbase = hledger-lsp
+	pkgdesc = Language Server Protocol (LSP) implementation for hledger journal files
+	pkgver = 0.2.4
+	pkgrel = 1
+	url = https://github.com/juev/hledger-lsp
+	arch = x86_64
+	license = MIT
+	makedepends = go
+	depends = glibc
+	source = https://github.com/juev/hledger-lsp/archive/v0.2.4/hledger-lsp-0.2.4.tar.gz
+	sha256sums = 9e28078739e0537f663acaf54e6e2dab992a295f9bd5ac1a80aa619b78d45762
+
+pkgname = hledger-lsp

.nvchecker.toml

@@ -0,0 +1,4 @@
+[hledger-lsp]
+source = "git"
+git = "https://github.com/juev/hledger-lsp.git"
+prefix = "v"

PKGBUILD

@@ -0,0 +1,31 @@
+# Maintainer: Caleb Maclennan <caleb@alerque.com>
+
+pkgname=hledger-lsp
+pkgver=0.2.4
+pkgrel=1
+pkgdesc='Language Server Protocol (LSP) implementation for hledger journal files'
+arch=(x86_64)
+license=(MIT)
+url="https://github.com/juev/$pkgname"
+depends=(glibc)
+makedepends=(go)
+_archive="$pkgname-$pkgver"
+source=("$url/archive/v$pkgver/$_archive.tar.gz")
+sha256sums=('9e28078739e0537f663acaf54e6e2dab992a295f9bd5ac1a80aa619b78d45762')
+
+build() {
+	cd "$_archive"
+	go build \
+		-trimpath \
+		-buildmode=pie \
+		-mod=readonly \
+		-modcacherw \
+		-ldflags "-linkmode external -extldflags \"$LDFLAGS\"" \
+		"./cmd/$pkgname"
+}
+
+package() {
+	cd "$_archive"
+	install -Dm0755 -t "$pkgdir/usr/bin/" "$pkgname"
+	install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
+}