From a5692c25fd6a5758f9e727c1ed9fedff07b7b646 Mon Sep 17 00:00:00 2001
From: Evert Vorster <evorster@gmail.com>
Date: Tue, 27 Jan 2026 13:10:13 +0200
Subject: [PATCH] Initial Commit

---
 .SRCINFO | 23 +++++++++++++++++++++++
 PKGBUILD | 45 +++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 68 insertions(+)
 create mode 100644 .SRCINFO
 create mode 100644 PKGBUILD

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..3dee2241da88
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,23 @@
+pkgbase = wine-nvoptix-git
+	pkgdesc = Relay for nvoptix to use with Wine (git)
+	pkgver = 0.3.r7.gc14b55a
+	pkgrel = 1
+	url = https://github.com/SveSop/wine-nvoptix
+	arch = x86_64
+	license = MIT
+	makedepends = git
+	makedepends = meson
+	makedepends = ninja
+	depends = glibc
+	depends = wine>=10.0
+	provides = wine-nvoptix
+	conflicts = wine-nvoptix
+	options = !strip
+	source = git+https://github.com/SveSop/wine-nvoptix.git
+	b2sums = SKIP
+
+pkgname = wine-nvoptix-git
+	depends = glibc
+	depends = wine>=10.0
+	depends = nvidia-utils
+	depends = wine-nvcuda
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..23947b6a04ef
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,45 @@
+# Maintainer: Evert Vorster
+# Contributor: Krzysztof Bogacki <krzysztof.bogacki@leancode.pl>
+
+pkgname=wine-nvoptix-git
+pkgver=0.3.r7.gc14b55a
+pkgrel=1
+pkgdesc='Relay for nvoptix to use with Wine (git)'
+arch=('x86_64')
+url='https://github.com/SveSop/wine-nvoptix'
+license=('MIT')
+depends=('glibc' 'wine>=10.0')
+makedepends=('git' 'meson' 'ninja')
+provides=('wine-nvoptix')
+conflicts=('wine-nvoptix')
+options=('!strip')
+source=('git+https://github.com/SveSop/wine-nvoptix.git')
+b2sums=('SKIP')
+
+pkgver() {
+    git -C "${srcdir}/wine-nvoptix" describe --tags | sed -E 's/^v//;s/-([0-9]+)-/-r\1-/;s/-/./g'
+}
+
+build() {
+    cd "${srcdir}/wine-nvoptix"
+
+    meson setup \
+        --cross-file ./build-wine64.txt \
+        --prefix /usr \
+        --libdir lib \
+        --buildtype release \
+        --strip \
+        -D fakedll=true \
+        ../build-wine64 .
+
+    ninja -C ../build-wine64
+}
+
+package() {
+    depends+=('nvidia-utils' 'wine-nvcuda')
+
+    DESTDIR="${pkgdir}" ninja -C "${srcdir}/build-wine64" install
+
+    install -Dm644 -t "${pkgdir}/usr/share/licenses/${pkgname}/" \
+        "${srcdir}"/wine-nvoptix/{COPYING.LIB,LICENSE}
+}