From 930a39c228e2975b1c4c41cd1865fa691d8dca38 Mon Sep 17 00:00:00 2001
From: Chih-Hsuan Yen <yan12125@gmail.com>
Date: Sat, 11 Jun 2022 10:56:39 +0800
Subject: [PATCH] new package

---
 .SRCINFO | 18 ++++++++++++++++++
 PKGBUILD | 36 ++++++++++++++++++++++++++++++++++++
 2 files changed, 54 insertions(+)
 create mode 100644 .SRCINFO
 create mode 100644 PKGBUILD

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..cebfd020d3bd
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,18 @@
+pkgbase = netron-cli
+	pkgdesc = Visualizer for neural network, deep learning, and machine learning models (CLI only)
+	pkgver = 5.8.6
+	pkgrel = 1
+	url = https://netron.app/
+	arch = any
+	license = MIT
+	makedepends = python-setuptools
+	makedepends = python-build
+	makedepends = python-installer
+	makedepends = python-wheel
+	depends = python
+	optdepends = python-onnx: serializing ONNX models
+	optdepends = python-pytorch: serializing PyTorch models
+	source = https://github.com/lutzroeder/netron/archive/v5.8.6/netron-5.8.6.tar.gz
+	sha256sums = 51abf2f70e47141016ed01c27eb0abdd7a26f3bae2a1f7b82cab23ae54d467d2
+
+pkgname = netron-cli
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..7e1d269a0aaa
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,36 @@
+# Maintainer: Chih-Hsuan Yen <yan12125@archlinux.org>
+
+pkgname=netron-cli
+pkgver=5.8.6
+pkgrel=1
+pkgdesc='Visualizer for neural network, deep learning, and machine learning models (CLI only)'
+url='https://netron.app/'
+arch=(any)
+license=(MIT)
+depends=(python)
+makedepends=(python-setuptools python-build python-installer python-wheel)
+optdepends=(
+  'python-onnx: serializing ONNX models'
+  'python-pytorch: serializing PyTorch models'
+)
+source=(https://github.com/lutzroeder/netron/archive/v$pkgver/netron-$pkgver.tar.gz)
+sha256sums=('51abf2f70e47141016ed01c27eb0abdd7a26f3bae2a1f7b82cab23ae54d467d2')
+
+prepare() {
+  cd netron-$pkgver
+  # Use dependencies from Arch
+  sed -i '/python -m pip/d' Makefile
+  # We don't need node_modules...trick Makefile
+  mkdir node_modules
+}
+
+build() {
+  cd netron-$pkgver
+  make build_python
+}
+
+package() {
+  cd netron-$pkgver
+  python -m installer --destdir="$pkgdir" dist/pypi/*.whl
+  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
+}