commit 901db2de9d012a7ca98a6abb019c998a110d8837
Author: Carsten Teibes <dev@f4ke.de>
Date:   Mon Jan 20 00:06:03 2014 +0100

    [add] enigma_sdl-svn

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..70ce426dc504
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,24 @@
+pkgbase = enigma_sdl-svn
+	pkgdesc = Puzzle game inspired by Oxyd on the Atari ST and Rock'n'Roll on the Amiga (development version)
+	pkgver = 1.20.r2383
+	pkgrel = 1
+	url = http://www.nongnu.org/enigma/
+	install = enigma_sdl.install
+	arch = i686
+	arch = x86_64
+	license = GPL
+	makedepends = imagemagick
+	makedepends = texi2html
+	makedepends = subversion
+	depends = sdl_image
+	depends = sdl_mixer
+	depends = sdl_ttf
+	depends = xerces-c
+	depends = hicolor-icon-theme
+	provides = enigma_sdl
+	conflicts = enigma_sdl
+	source = enigma_sdl::svn+http://svn.code.sf.net/p/enigma-game/source/trunk
+	md5sums = SKIP
+
+pkgname = enigma_sdl-svn
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..18e28bdb7e07
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,45 @@
+# Maintainer: carstene1ns <url/mail: arch carsten-teibes de>
+# Contributor: Nagy Gabor <ngaba@@bibl..u-szeged..hu>
+
+_pkgbase=enigma_sdl
+pkgname=$_pkgbase-svn
+pkgver=1.20.r2383
+pkgrel=1
+arch=('i686' 'x86_64')
+license=('GPL')
+pkgdesc="Puzzle game inspired by Oxyd on the Atari ST and Rock'n'Roll on the Amiga (development version)"
+url="http://www.nongnu.org/enigma/"
+depends=('sdl_image' 'sdl_mixer' 'sdl_ttf' 'xerces-c' 'hicolor-icon-theme')
+makedepends=('imagemagick' 'texi2html' 'subversion')
+conflicts=("$_pkgbase")
+provides=("$_pkgbase")
+install=$_pkgbase.install
+source=($_pkgbase::"svn+http://svn.code.sf.net/p/enigma-game/source/trunk")
+md5sums=('SKIP')
+
+pkgver() {
+  cd $_pkgbase
+  # get version from autotools
+  local ver="$(grep 'AC_INIT(.*)' configure.ac | sed 's/[^0-9\.]*//g')"
+  local rev="$(svnversion)"
+  printf "%s.r%s" "$ver" "${rev//[[:alpha:]]}"
+}
+
+build() {
+  cd $_pkgbase
+
+  ./autogen.sh
+  ./configure --prefix=/usr --program-suffix=_sdl --enable-optimize
+  make
+}
+
+package() {
+  cd $_pkgbase
+
+  make DESTDIR="$pkgdir/" install
+
+  # removing enet files to avoid file conflicts
+  rm -rf "$pkgdir"/usr/{include,lib}
+  # correct name
+  sed 's/Exec=enigma$/&_sdl/g' -i "$pkgdir"/usr/share/applications/enigma.desktop
+}
diff --git a/enigma_sdl.install b/enigma_sdl.install
new file mode 100644
index 000000000000..478b46b2b1ae
--- /dev/null
+++ b/enigma_sdl.install
@@ -0,0 +1,12 @@
+
+post_install() {
+  xdg-icon-resource forceupdate --theme hicolor &> /dev/null
+}
+
+post_upgrade() {
+  post_install
+}
+
+post_remove() {
+  post_install
+}