Create figma-agent-linux package

.SRCINFO

@@ -0,0 +1,16 @@
+pkgbase = figma-agent-linux
+	pkgdesc = Figma Agent for Linux
+	pkgver = 0.1.0
+	pkgrel = 1
+	url = https://github.com/neetly/figma-agent-linux
+	arch = x86_64
+	arch = aarch64
+	license = MIT
+	makedepends = git
+	makedepends = rust
+	depends = freetype2
+	depends = fontconfig
+	source = figma-agent-linux::git+https://github.com/neetly/figma-agent-linux.git#tag=v0.1.0
+	cksums = SKIP
+
+pkgname = figma-agent-linux

.gitignore

@@ -0,0 +1,4 @@
+/*
+!/.gitignore
+!/PKGBUILD
+!/.SRCINFO

PKGBUILD

@@ -0,0 +1,30 @@
+# Maintainer: Hikari Hayashi <rev.hikari@gmail.com>
+
+pkgname=figma-agent-linux
+pkgver=0.2.0
+pkgrel=1
+pkgdesc="Figma Agent for Linux"
+url="https://github.com/neetly/figma-agent-linux"
+license=(MIT)
+arch=(x86_64 aarch64)
+depends=(freetype2 fontconfig)
+makedepends=(git rust)
+source=("$pkgname::git+https://github.com/neetly/figma-agent-linux.git#tag=v$pkgver")
+cksums=(SKIP)
+
+prepare() {
+  cd "$srcdir/$pkgname"
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+  cd "$srcdir/$pkgname"
+  cargo build --frozen --release --target "$CARCH-unknown-linux-gnu"
+}
+
+package() {
+  cd "$srcdir/$pkgname"
+  install -Dm755 "./target/$CARCH-unknown-linux-gnu/release/figma-agent" "$pkgdir/usr/bin/figma-agent"
+  install -Dm644 "./LICENSE" "$pkgdir/usr/share/licenses/figma-agent/LICENSE"
+  install -Dm644 "./figma-agent.service" "$pkgdir/usr/lib/systemd/user/figma-agent.service"
+}