Bump version to 2.3.4

.SRCINFO

@@ -0,0 +1,14 @@
+pkgbase = python-trame-vtk
+	pkgdesc = VTK widgets for trame
+	pkgver = 2.3.4
+	pkgrel = 1
+	url = https://github.com/Kitware/trame-vtk
+	arch = any
+	license = custom:BSD-3-clause
+	checkdepends = python-pytest
+	makedepends = python-setuptools
+	depends = python-trame-client
+	source = trame-vtk-2.3.4.tar.gz::https://github.com/Kitware/trame-vtk/archive/v2.3.4.tar.gz
+	sha512sums = b7108a8cb53e269b1bdbb33d9a06f74eea66574ea9b3938cde3958e9479283d596b2be02ec467d7fd14e09d77de74a68be9886073f32e5dffe7092a8fb43ad36
+
+pkgname = python-trame-vtk

.gitignore

@@ -0,0 +1 @@
+*

PKGBUILD

@@ -0,0 +1,39 @@
+# Maintainer: Carlos Aznarán <caznaranl@uni.pe>
+_base=trame-vtk
+pkgname=python-${_base}
+pkgdesc="VTK widgets for trame"
+pkgver=2.3.4
+pkgrel=1
+arch=(any)
+url="https://github.com/Kitware/${_base}"
+license=('custom:BSD-3-clause')
+depends=(python-trame-client)
+makedepends=(python-setuptools)
+checkdepends=(python-pytest)
+source=(${_base}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz)
+sha512sums=('b7108a8cb53e269b1bdbb33d9a06f74eea66574ea9b3938cde3958e9479283d596b2be02ec467d7fd14e09d77de74a68be9886073f32e5dffe7092a8fb43ad36')
+
+prepare() {
+  sed -i 's/^graft/#graft/' ${_base}-${pkgver}/MANIFEST.in
+  sed -i 's/^include/#include/' ${_base}-${pkgver}/MANIFEST.in
+}
+
+build() {
+  cd ${_base}-${pkgver}
+  python setup.py build
+}
+
+check() {
+  cd ${_base}-${pkgver}
+  python -m pytest
+}
+
+package() {
+  cd ${_base}-${pkgver}
+  PYTHONPYCACHEPREFIX="${PWD}/.cache/cpython/" python setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1 --skip-build
+  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
+  rm ${pkgdir}${site_packages}/trame/__init__.py
+  rm ${pkgdir}${site_packages}/trame/modules/__init__.py
+  rm ${pkgdir}${site_packages}/trame/widgets/__init__.py
+}