commit 54843e8cc45e9fe10d1d3f4af88f60a0b3692e6e
Author: oritwoen <dominik.opyd@gmail.com>
Date:   Sun Dec 14 16:24:20 2025 +0000

    chore: update to v0.1.0

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 0000000000000..ddce7effc8e88
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,18 @@
+pkgbase = kangaroo
+	pkgdesc = Pollard's Kangaroo ECDLP solver for secp256k1 using Vulkan/Metal/DX12 compute
+	pkgver = 0.1.0
+	pkgrel = 1
+	url = https://github.com/oritwoen/kangaroo
+	arch = x86_64
+	license = MIT
+	makedepends = git
+	makedepends = rust
+	makedepends = vulkan-headers
+	depends = gcc-libs
+	depends = glibc
+	depends = vulkan-icd-loader
+	optdepends = vulkan-validation-layers: for debugging
+	source = git+https://github.com/oritwoen/kangaroo.git#tag=v0.1.0
+	sha256sums = SKIP
+
+pkgname = kangaroo
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 0000000000000..4df09c0134742
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,35 @@
+pkgname=kangaroo
+pkgver=0.1.0
+pkgrel=1
+pkgdesc="Pollard's Kangaroo ECDLP solver for secp256k1 using Vulkan/Metal/DX12 compute"
+arch=('x86_64')
+url="https://github.com/oritwoen/kangaroo"
+license=('MIT')
+depends=('gcc-libs' 'glibc' 'vulkan-icd-loader')
+makedepends=('git' 'rust' 'vulkan-headers')
+optdepends=('vulkan-validation-layers: for debugging')
+source=("git+https://github.com/oritwoen/kangaroo.git#tag=v$pkgver")
+sha256sums=('SKIP')
+
+prepare() {
+  cd "$pkgname"
+  cargo fetch --locked --target "$(rustc --print host-tuple)"
+}
+
+build() {
+  cd "$pkgname"
+  export CFLAGS+=" -ffat-lto-objects"
+  cargo build --release --locked --offline
+}
+
+check() {
+  cd "$pkgname"
+  cargo test --locked --offline
+}
+
+package() {
+  cd "$pkgname"
+  install -Dm755 "target/release/$pkgname" "$pkgdir/usr/bin/$pkgname"
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+  install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
+}