commit 390fbc36d0b6cb4154eb70c8c3fc79c06b2fb5fb
Author: pathin <aur@pathin.me>
Date:   Sun Feb 22 02:43:03 2026 +0000

    Update PKGBUILD and .SRCINFO with GitHub Actions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 0000000000000..231d43efcc92b
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,19 @@
+pkgbase = onset-git
+	pkgdesc = Lightweight XDG autostart manager for Linux
+	pkgver = r12.c44a8b8
+	pkgrel = 1
+	url = https://github.com/xPathin/onset
+	arch = x86_64
+	arch = aarch64
+	license = MIT
+	makedepends = rust
+	makedepends = cargo
+	makedepends = git
+	depends = gtk4
+	depends = libadwaita
+	provides = onset
+	conflicts = onset
+	source = git+https://github.com/xPathin/onset.git
+	sha256sums = SKIP
+
+pkgname = onset-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 0000000000000..8d81caaf6c34e
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,43 @@
+# Maintainer: Patrick Fischer <aur at pathin dot me>
+pkgname=onset-git
+pkgver=r12.c44a8b8
+pkgrel=1
+pkgdesc="Lightweight XDG autostart manager for Linux"
+arch=('x86_64' 'aarch64')
+url="https://github.com/xPathin/onset"
+license=('MIT')
+depends=('gtk4' 'libadwaita')
+makedepends=('rust' 'cargo' 'git')
+provides=('onset')
+conflicts=('onset')
+source=("git+https://github.com/xPathin/onset.git")
+sha256sums=('SKIP')
+
+pkgver() {
+    cd onset
+    if DESC=$(git describe --long --tags --abbrev=7 2>/dev/null); then
+        echo "$DESC" | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+    else
+        printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
+    fi
+}
+
+build() {
+    cd onset
+    cargo build --release --locked
+}
+
+check() {
+    cd onset
+    cargo test --release --locked
+}
+
+package() {
+    cd onset
+    install -Dm755 "target/release/onset" "$pkgdir/usr/bin/onset"
+    install -Dm644 "data/com.github.xPathin.onset.desktop" \
+        "$pkgdir/usr/share/applications/com.github.xPathin.onset.desktop"
+    install -Dm644 "data/icons/hicolor/scalable/apps/com.github.xPathin.onset.svg" \
+        "$pkgdir/usr/share/icons/hicolor/scalable/apps/com.github.xPathin.onset.svg"
+    install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}