commit 1876e76bc4fd218cd233a81bdbf06de421ddd99b
Author: xiota <aur@mentalfossa.com>
Date:   Sun Feb 22 01:44:21 2026 +0000

    2.0.21.r4

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 0000000000000..f12f268de4cf3
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,18 @@
+pkgbase = rats-search-qt6-git
+	pkgdesc = BitTorrent P2P multi-platform search engine with integrated torrent client
+	pkgver = 2.0.21.r4.g2872fbd
+	pkgrel = 1
+	url = https://github.com/DEgITx/rats-search
+	arch = x86_64
+	license = MIT
+	makedepends = cmake
+	makedepends = git
+	makedepends = ninja
+	makedepends = qt6-tools
+	depends = qt6-websockets
+	provides = rats-search
+	conflicts = rats-search
+	source = rats-search::git+https://github.com/DEgITx/rats-search.git
+	sha256sums = SKIP
+
+pkgname = rats-search-qt6-git
diff --git a/.gitignore b/.gitignore
new file mode 100644
index 0000000000000..018a3de081444
--- /dev/null
+++ b/.gitignore
@@ -0,0 +1,4 @@
+*
+!PKGBUILD
+!.SRCINFO
+!.gitignore
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 0000000000000..097eada0816d9
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,57 @@
+# Maintainer:
+
+_pkgname="rats-search"
+pkgname="$_pkgname-qt6-git"
+pkgver=2.0.21.r4.g2872fbd
+pkgrel=1
+pkgdesc="BitTorrent P2P multi-platform search engine with integrated torrent client"
+url="https://github.com/DEgITx/rats-search"
+license=("MIT")
+arch=("x86_64")
+
+depends=(
+  'qt6-websockets'
+)
+makedepends=(
+  'cmake'
+  'git'
+  'ninja'
+  'qt6-tools'
+)
+
+provides=("$_pkgname")
+conflicts=("$_pkgname")
+
+_pkgsrc="$_pkgname"
+source=("$_pkgsrc"::"git+$url.git")
+sha256sums=('SKIP')
+
+prepare() {
+  cd "$_pkgsrc"
+  git submodule update --init --depth=1
+}
+
+pkgver() {
+  cd "$_pkgsrc"
+  git describe --long --tags --abbrev=7 --exclude='*[a-zA-Z][a-zA-Z]*' \
+    | sed -E 's/^[^0-9]*//;s/([^-]*-g)/r\1/;s/-/./g'
+}
+
+build() {
+  local _cmake_options=(
+    -B build
+    -S "$_pkgsrc"
+    -G Ninja
+    -DCMAKE_BUILD_TYPE=None
+    -DCMAKE_INSTALL_PREFIX='/usr'
+    -Wno-dev
+  )
+
+  cmake "${_cmake_options[@]}"
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+  install -Dm644 "$_pkgsrc/LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname/"
+}