Initial commit

.SRCINFO

@@ -0,0 +1,19 @@
+pkgbase = kazumi
+	pkgdesc = 基于自定义规则的番剧采集APP，支持流媒体在线观看，支持弹幕
+	pkgver = 1.7.3
+	pkgrel = 1
+	url = https://github.com/Predidit/Kazumi
+	arch = x86_64
+	license = GPL-3.0-or-later
+	makedepends = clang
+	makedepends = cmake
+	makedepends = ninja
+	makedepends = fvm
+	depends = gtk3
+	depends = libayatana-appindicator
+	depends = webkit2gtk-4.1
+	depends = mpv
+	source = kazumi-1.7.3.tar.gz::https://github.com/Predidit/Kazumi/archive/refs/tags/1.7.3.tar.gz
+	sha256sums = db53a8ce44ee526f6b67b19ef663a5c2efcd717884028b5260eeb7a7ed90527b
+
+pkgname = kazumi

PKGBUILD

@@ -0,0 +1,47 @@
+# Maintainer: Integral <integral@member.fsf.org>
+
+pkgname=kazumi
+_srcname=Kazumi
+pkgver=1.7.3
+pkgrel=1
+pkgdesc="基于自定义规则的番剧采集APP，支持流媒体在线观看，支持弹幕"
+url="https://github.com/Predidit/Kazumi"
+license=('GPL-3.0-or-later')
+arch=('x86_64')
+depends=('gtk3' 'libayatana-appindicator' 'webkit2gtk-4.1' 'mpv')
+makedepends=('clang' 'cmake' 'ninja' 'fvm')
+source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/${pkgver}.tar.gz")
+sha256sums=('db53a8ce44ee526f6b67b19ef663a5c2efcd717884028b5260eeb7a7ed90527b')
+
+prepare() {
+	cd "${_srcname}-${pkgver}/"
+	fvm install stable
+	fvm use stable -f
+	fvm flutter --disable-analytics
+	fvm flutter --no-version-check pub get
+}
+
+build() (
+	cd "${_srcname}-${pkgver}/"
+	fvm flutter build linux --no-pub --release
+)
+
+package() {
+	cd "${_srcname}-${pkgver}/"
+
+	pushd build/linux/x64/release
+	install -Dm755 "bundle/${pkgname}" -t "${pkgdir}/usr/lib/${pkgname}/"
+	cmake -DCMAKE_INSTALL_PREFIX="${pkgdir}/usr/lib/${pkgname}" .
+        cmake -P cmake_install.cmake
+	popd
+
+	# Use system-provided libmpv
+	rm "${pkgdir}/usr/lib/${pkgname}/lib/libmpv.so.2"
+
+	install -dm755 "${pkgdir}/usr/bin"
+	ln -s "/usr/lib/${pkgname}/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
+
+	local _app_id="io.github.Predidit.Kazumi"
+	install -Dm644 "assets/images/logo/logo_linux.png" "${pkgdir}/usr/share/icons/hicolor/512x512/apps/${_app_id}.png"
+	install -Dm644 "assets/linux/${_app_id}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
+}